PONG_VHDL

[kroszkanorber]

Witam.

Próbując moich sił w opisywaniu układów postanowiłem opisać prostą grę PONG. Jestem ambitny i nie wystarczy mi kropka na ekranie i dwie kreski postanowiłem urozmaicić grę kolorami i dodałem 5 kierunków odbić piłeczki paletkami. Grę po uruchomieniu aktywujemy przyciskiem ENTER. Przyciskiem SPACE zatrzymujemy grę i ustawiamy liczniki zdobytych punktów na 0 - 0. Przyciskami P i L na klawiaturze poruszamy lewą paletką w górę i w dół, a Przyciskami Q i A Plaetką lewą.

Układ FPGA jaest zasilany z generatora 100MHz i przyciskiem RESET aktywny = '0'.

W kodzie VHDL jest obsługiwana klawiatura PS2, Monitor VGA 640x480, Kolory 8 Bit oznaczone jako RGB. bit7, bit6 = niebieski. bit5, bit4, bit3 = zielony. pozostałe = czerwony. Odsyłam do projektu VGA-DIY w którym są podane wrtości rezystorów podpiętych do złącza VGA.

PS2_C i PS2_D złącze klawiatury Clk i Dat. 

Życzę udanej rozgrywki.

Dla ciekawych wstawiam kod VHDL.

----------------------------------------------------------------------------------
-- Company: 
-- Engineer: 		 Norbert Kroszka
-- 
-- Create Date:    14:12:34 09/30/2023 
-- Design Name: 	 Pong
-- Module Name:    Pong - Behavioral 
-- Project Name: 
-- Target Devices: xc3s200a
-- Tool versions:
-- Description: 
--
-- Dependencies: 
--
-- Revision: 		V1
-- Revision 0.01 - File Created
-- Additional Comments: 
-- Enter : Przerwa w grze lub rozpoczęcie gry
-- Spacja : Rozpoczęcie gry, kasowanie wyników
-- P : paletka prawa przesuwanie w górę
-- L : paletka prawa przsuwanie w dół
-- Q : paletka lewa przesuwanie w górę
-- A : paletka leaw przsuwanie w dół
----------------------------------------------------------------------------------
library IEEE;
use IEEE.STD_LOGIC_1164.ALL;
use IEEE.STD_LOGIC_ARITH.ALL;
use IEEE.STD_LOGIC_UNSIGNED.ALL;

-- Uncomment the following library declaration if using
-- arithmetic functions with Signed or Unsigned values
--use IEEE.NUMERIC_STD.ALL;

-- Uncomment the following library declaration if instantiating
-- any Xilinx primitives in this code.
--library UNISIM;
--use UNISIM.VComponents.all;

entity Pong is
    Port ( Clk : in  STD_LOGIC;    -- 100 MHz !!! musi być. bez tego nie ruszy :)
           Reset : in  STD_LOGIC;
           BUZ : out  STD_LOGIC;
           PS2_D : in  STD_LOGIC;
           PS2_C : in  STD_LOGIC;
           VS : out  STD_LOGIC;
           HS : out  STD_LOGIC;
           RGB : out  STD_LOGIC_VECTOR (7 downto 0)
			  );
end Pong;

architecture Behavioral of Pong is

---------------------HS,VS, BL------------------------------
signal Cnt25 : std_logic_vector (1 downto 0) ;
signal EnH : std_logic;
signal CntH : std_logic_vector (9 downto 0) ;
signal EnV : std_logic;
signal CntV : std_logic_vector (9 downto 0) ;
signal Bl : std_logic ;
-------------------------GRA--------------------------------

signal SWReset : std_logic;
signal SWPause : std_logic;
signal SW1 : std_logic;
signal SW2 : std_logic;
signal SW3 : std_logic;
signal SW4 : std_logic;

signal DisClk : std_logic;
signal EnClk0 : std_logic;
signal EnClk1 : std_logic;
signal EnClk2 : std_logic;
signal EnClkH : std_logic;
signal EnClkV : std_logic;
signal EnDiv : std_logic;
signal CntDiv : std_logic_vector(7 downto 0);

signal Linia : std_logic;
signal Linia1 : std_logic;
signal Linia2 : std_logic;
signal Linia3 : std_logic;
signal Linia4 : std_logic;
signal Linia5 : std_logic;
signal Linia6 : std_logic;
signal Linia7 : std_logic;

signal Paletka : std_logic;
signal PaletkaL : std_logic;
signal PaletkaR : std_logic;
signal PaletkaLEnd : std_logic;
signal PaletkaREnd : std_logic;
signal PaletkaLReg : std_logic_vector (9 downto 0) := "0011110000";
signal PaletkaRReg : std_logic_vector (9 downto 0) := "0011110000" ;
signal PaletkaLS : std_logic;
signal PaletkaLGS : std_logic;
signal PaletkaLG : std_logic;
signal PaletkaLDS : std_logic;
signal PaletkaLD : std_logic;
signal PaletkaRS : std_logic;
signal PaletkaRGS : std_logic;
signal PaletkaRG : std_logic;
signal PaletkaRDS : std_logic;
signal PaletkaRD : std_logic;
signal PaletkaS : std_logic;
signal PaletkaGS : std_logic;
signal PaletkaG : std_logic;
signal PaletkaDS : std_logic;
signal PaletkaD : std_logic;
signal PaletkaGUD : std_logic;
signal PaletkaDUD : std_logic;
signal PaletkaGDS : std_logic;
signal PaletkaGD : std_logic;

signal Pilka : std_logic;
signal PilkaH : std_logic;
signal PilkaV : std_logic;

signal PilkaRL : std_logic;
signal PilkaLEnd : std_logic;
signal PilkaREnd : std_logic;
signal PilkaRegHLEnd : std_logic;
signal PilkaRegHREnd : std_logic;
signal PilkaRegHUDEnd : std_logic;

signal PilkaUD : std_logic;
signal PilkaRegVUEnd : std_logic;
signal PilkaRegVDEnd : std_logic;

signal PilkaRegH : std_logic_vector (9 downto 0) := "0101000000";
signal PilkaRegV : std_logic_vector (9 downto 0) := "0011110000";
signal PilkaUDCnt : std_logic_vector (1 downto 0) ;

signal Seg : std_logic;
signal SegHL : std_logic;
signal SegHL1 : std_logic;
signal SegHR : std_logic;
signal SegHR1 : std_logic;
signal SegHLL : std_logic;
signal SegHRR: std_logic;
signal SegHU : std_logic;
signal SegHM : std_logic;
signal SegHD : std_logic;
signal SegVU : std_logic;
signal SegVD : std_logic;
signal SegA : std_logic;
signal SegB : std_logic;
signal SegC : std_logic;
signal SegD : std_logic;
signal SegE : std_logic;
signal SegF : std_logic;
signal SegG : std_logic;
signal SegAand : std_logic;
signal SegBand : std_logic;
signal SegCand : std_logic;
signal SegDand : std_logic;
signal SegEand : std_logic;
signal SegFand : std_logic;
signal SegGand : std_logic;
signal SegA1 : std_logic;
signal SegB1 : std_logic;
signal SegC1 : std_logic;
signal SegD1 : std_logic;
signal SegE1 : std_logic;
signal SegF1 : std_logic;
signal SegG1 : std_logic;
signal SegA1and : std_logic;
signal SegB1and : std_logic;
signal SegC1and : std_logic;
signal SegD1and : std_logic;
signal SegE1and : std_logic;
signal SegF1and : std_logic;
signal SegG1and : std_logic;

signal CntL : std_logic_vector(3 downto 0);
signal CntL1 : std_logic_vector(3 downto 0);
signal PilkaL : std_logic;
signal PilkaL1 : std_logic;
signal SegL : std_logic_vector(6 downto 0);
signal SegL1 : std_logic_vector(6 downto 0);

signal CntPizo : std_logic_vector(4 downto 0);

signal KoniecGry : std_logic;

---------------------- sygnały obsługi klawiatury PS2----------------------------
signal D : std_logic_vector (9 downto 0) ;
signal Din : std_logic_vector (7 downto 0) ;
signal Cnt : std_logic_vector (7 downto 0) ;

signal PS2_Cin : std_logic;
signal PS2_Clk : std_logic;
signal Brake : std_logic;


type PS2State_type is (idle, datain, sel); 
signal PS2State : PS2State_type;

begin

---------------------- SYNC, CNT----------------------------
process(Clk)
begin
	if Clk'event and Clk = '0' then
		Cnt25 <= Cnt25 + 1 ;
	end if;
end process;

EnH <= Cnt25(1) and Cnt25(0);

process(Clk, EnH)
begin
	if Clk'event and Clk = '0' then
		if EnH = '1' then
			if CntH = 799 then
				CntH <= ( others => '0');
			else
				CntH <= CntH + 1;
			end if;
		end if;
	end if;
end process;

EnV <= '1' when (Cnt25 = "11") and (CntH = 799) else '0';

process(Clk, Cnt25, EnV)
begin
	if Clk'event and Clk = '0' then
		if EnV = '1' then
			if CntV = 524 then
				CntV <= ( others => '0');
			else
				CntV <= CntV + 1;
			end if;
		end if;
	end if;
end process;

EnDiv <= '1' when (Cnt25 = "11") and (CntH = 799) else '0';

process(Clk, Cnt25, EnV)
begin
	if Clk'event and Clk = '0' then
		if EnDiv = '1' then
			CntDiv <= CntDiv + 1;
		end if;
	end if;
end process;

HS <= '0' when ((CntH > 655) and (CntH < 753)) else '1';	--dekoder sygnału synchronizacji poziomej
BL <= '0' when ((CntH > 639) or (CntV > 479)) else '1';	--dekoder wygaszania obrazu poza obszarem wyświetlanym
VS <= '0' when ((CntV > 489) and (CntV < 493)) else '1';	--dekoder sygnału synchronizacji pionowej
-------------------------VGA obraz----------------------------
process(Clk, Cnt25, BL, Paletka, Linia, Seg, Pilka)
begin
	if Clk'event and Clk = '0' then
		if Cnt25 = "10" then
			if BL = '0' then
				RGB <= (others => '0');
			else
				if Pilka = '1' then
					RGB <= "00111111";     		 --piłka kolor
				elsif Linia = '1' then
					RGB <= (others => '1');     --linie kolor biały
				elsif Paletka = '1' then
					RGB <= "00000111";          --paletki kolor czerwony
				elsif Seg = '1' then
					RGB <= "11000000";          --wynik meczu kolor niebieski
				else
					RGB <= "10110000";			 --boisko kolor zielony
				end if;
			end if;
		end if;
	end if;
end process;

Paletka <= PaletkaL or PaletkaR;
Linia <= Linia1 or Linia2 or Linia3 or Linia7;

------------------------GRA Linia boiska na wyświetlaczu------------------------

Linia1 <= '1' when (CntV(9 downto 3) = "0000000") else '0';								--linie na górze i dole
Linia2 <= '1' when (CntV(9 downto 3) = "0111011") else '0';

Linia3 <= (Linia4 and Linia6) or (Linia5 and Linia6); 									--linie z prawej i lewej strony
Linia4 <= '1' when (CntH(9 downto 3) = "0000000") else '0';
Linia5 <= '1' when (CntH(9 downto 3) = "1001111") else '0';
Linia6 <= '0' when (CntV(9 downto 3) > "0000011") and (CntV(9 downto 3) < "0111000") else '1';

Linia7 <= '1' when (CntH(9 downto 2) = "01010000") and (CntV(3) = '1') else '0'; --linia przerywana na środku

-------------------------GRA Pilka na wyświetlaczu------------------------

PilkaH <= '1' when ((CntH >= PilkaRegH) and (CntH <= (PilkaRegH + "11"))) else '0';				
PilkaV <= '1' when ((CntV >= PilkaRegV) and (CntV <= (PilkaRegV + "11"))) else '0';
Pilka <= PilkaH and PilkaV; 														  --dekoder obrazu płki na ekranie monitra
------------------------------------------------------------------------------------------
DisClk <= '0';																					  --piłka brak ruchu
EnClk0 <= '1' when (CntDiv = "11111111") and EnDiv = '1' else '0';			  --piłka
EnClk1 <= '1' when (CntDiv(6 downto 0) = "1111111") and EnDiv = '1' else '0';--piłka
EnClk2 <= '1' when (CntDiv(5 downto 0) = "111111") and EnDiv = '1' else '0'; --piłka paletki
------------------------------------------------------------------------------------------
PaletkaLS <= '1' when (PilkaRegV >= (PaletkaLReg - "0011"))					 --dekoder środka paletki
						 and (PilkaRegV <= (PaletkaLReg + "0011"))
						 and PilkaRegHLEnd = '1' else '0';
PaletkaLGS <= '1' when (PilkaRegV < (PaletkaLReg - "0011"))					 --dekoder górnej części paletki
						 and (PilkaRegV >= (PaletkaLReg - "1110"))
						 and PilkaRegHLEnd = '1' else '0';
PaletkaLG <= '1' when (PilkaRegV < (PaletkaLReg - "1110"))					 --dekoder górnej zewnętrznej części paletki
						 and (PilkaRegV >= (PaletkaLReg - "1111"))
						 and PilkaRegHLEnd = '1' else '0';
PaletkaLDS <= '1' when (PilkaRegV > (PaletkaLReg + "0011"))					 --dekoder dolnej części paletki
						 and (PilkaRegV <= (PaletkaLReg + "1110"))
						 and PilkaRegHLEnd = '1' else '0';
PaletkaLD <= '1' when (PilkaRegV > (PaletkaLReg + "1110"))					 --dekoder dolnej zewnętrznej części paletki
						 and (PilkaRegV <= (PaletkaLReg + "1111"))
						 and PilkaRegHLEnd = '1' else '0';
------------------------------------------------------------------------------------------
PaletkaRS <= '1' when (PilkaRegV >= (PaletkaRReg - "0011"))					 --dekoder środka paletki
						 and (PilkaRegV <= (PaletkaRReg + "0011"))
						 and PilkaRegHREnd = '1' else '0';
PaletkaRGS <= '1' when (PilkaRegV < (PaletkaRReg - "0011"))					 --dekoder górnej części paletki
						 and (PilkaRegV >= (PaletkaRReg - "1110"))
						 and PilkaRegHREnd = '1' else '0';
PaletkaRG <= '1' when (PilkaRegV < (PaletkaRReg - "1110"))					 --dekoder górnej zewnętrznej części paletki
						 and (PilkaRegV >= (PaletkaRReg - "1111"))
						 and PilkaRegHREnd = '1' else '0';
PaletkaRDS <= '1' when (PilkaRegV > (PaletkaRReg + "011"))					 --dekoder dolnej części paletki
						 and (PilkaRegV <= (PaletkaRReg + "1110"))
						 and PilkaRegHREnd = '1' else '0';
PaletkaRD <= '1' when (PilkaRegV > (PaletkaRReg + "1110"))					 --dekoder dolnej zewnętrznej części paletki
						 and (PilkaRegV <= (PaletkaRReg + "1111"))
						 and PilkaRegHREnd = '1' else '0';
------------------------------------------------------------------------------------------
PaletkaS <= PaletkaLS or PaletkaRS;
PaletkaGS <= PaletkaLGS or PaletkaRGS;
PaletkaG <= PaletkaLG or PaletkaRG;
PaletkaDS <= PaletkaLDS or PaletkaRDS;
PaletkaD <= PaletkaLD or PaletkaRD;
PaletkaGUD <= PaletkaG or PaletkaGS;
PaletkaDUD <= PaletkaD or PaletkaDS;
PaletkaGDS <= PaletkaGS or PaletkaDS;
PaletkaGD <= PaletkaG or PaletkaD;

process(Clk, Reset, SWReset, ENClkH, PaletkaS, PaletkaGDS, PaletkaGD)
begin
	if (Reset = '0') or (SWReset = '0') then
		PilkaUDCnt <= "01";
	else
		if Clk'event and Clk = '0' then
			if ENClkH = '1' then
				if PaletkaS = '1' then
					PilkaUDCnt <= "00";
					
			elsif PaletkaGDS = '1' then
					PilkaUDCnt <= "01";
					
			elsif PaletkaGD = '1' then
					PilkaUDCnt <= "10";
				end if;
			end if;
		end if;
	end if;
end process;

	with PilkaUDCnt select
	ENClkV <= ENClk1 when "01",
				 ENClk1 when "10",
				 DisClk when others;

	with PilkaUDCnt select
	ENClkH <= ENClk1 when "01",
				 ENClk0 when "10",
				 ENClk2 when others;
				 
	
	
------------------------------------------------------------------------------------------
PilkaRegVUEnd <= '1' when (PilkaRegV(9 downto 3) = "0000000") else '0';--dekodery górnego i dolnego odbicia piłki 
PilkaRegVDEnd <= '1' when (PilkaRegV(9 downto 3) = "0111011") else '0';

process(Clk, PilkaRegHLEnd, PilkaRegHREnd, PaletkaDUD, PaletkaGUD)
begin
	if Clk'event and Clk = '0' then
		if (PilkaRegVUEnd = '1') or (PaletkaDUD = '1') then
			PilkaUD <= '1';																--flaga zmiany kierunku w pionie
		elsif (PilkaRegVDEnd = '1') or (PaletkaGUD = '1') then
			PilkaUD <= '0';
		end if;
	end if;
end process;
------------------------------------------------------------------------------------------
PilkaRegHUDEnd <= '0' when (PilkaRegV(9 downto 3) > "0000011")  			 --dekoder odbić piłki Górna i dolna linia
							and (PilkaRegV(9 downto 3) < "0111000") else '1';
							
PilkaRegHLEnd <= '1' when (PilkaRegH(9 downto 3) = "0000000") else '0';  --dekoder odbić piłki od paletki lewa strona
PaletkaLEnd <= '1' when (PilkaRegV >= (PaletkaLReg - "1111"))
						 and (PilkaRegV <= (PaletkaLReg + "1111"))
						 and PilkaRegHLEnd = '1' else '0';
						 
PilkaRegHREnd <= '1' when (PilkaRegH(9 downto 3) = "1001111") else '0';  --dekoder odbić piłki od paletki prawa strona
PaletkaREnd <= '1' when (PilkaRegV >= (PaletkaRReg - "1111"))
						 and (PilkaRegV <= (PaletkaRReg + "1111"))
						 and PilkaRegHREnd = '1' else '0';
						 
PilkaLEnd <= (PilkaRegHLEnd and PilkaRegHUDEnd) or PaletkaLEnd; 			--dekoder odbić piłki lewa strona
PilkaREnd <= (PilkaRegHREnd and PilkaRegHUDEnd) or PaletkaREnd; 			--dekoder odbić piłki prawa strona

process(Clk, PilkaRegHLEnd, PilkaRegHREnd)
begin
	if Clk'event and Clk = '0' then
		if PilkaLEnd = '1' then
			PilkaRL <= '1';																--flaga zmiany kierunku w poziomie
		elsif PilkaREnd = '1' then
			PilkaRL <= '0';
		end if;
	end if;
end process;
------------------------------------------------------------------------------------------
process(Clk, EnClkH, PilkaRL, KoniecGry, Reset, SWReset, SWPause)
begin
	if (Reset = '0') or (SWReset = '0') then
		PilkaRegH <= "0101000000";
	else		
		if Clk'event and Clk = '0' then
			if EnClkH = '1' then
				if (KoniecGry = '0') and (SWPause = '0') then
					if PilkaRL = '1' then
						PilkaRegH <= PilkaRegH + 1;   --licznik przesuwającej się piłki w poziomie w prawo
					else
						PilkaRegH <= PilkaRegH - 1;   --licznik przesuwającej się piłki w poziomie w lewo
					end if;
				end if;
			end if;
		end if;
	end if;
end process;

process(Clk, EnClkV, PilkaUD, KoniecGry, Reset, SWReset, SWPause)
begin
	if (Reset = '0') or (SWReset = '0') then
		PilkaRegV <= "0011110000";
	else		
		if Clk'event and Clk = '0' then
			if EnClkV = '1' then
				if (KoniecGry = '0') and (SWPause = '0') then
					if PilkaUD = '1' then
						PilkaRegV <= PilkaRegV + 1;   --licznik przesuwającej się piłki w pionie w dół
					else
						PilkaRegV <= PilkaRegV - 1;   --licznik przesuwającej się piłki w pionie w górę
					end if;
				end if;
			end if;
		end if;
	end if;
end process;

-------------------------GRA Paletki na wyświetlaczu---------------------- 

process(Clk, EnClk2, SW3, SW4)
begin
	if Clk'event and Clk = '0' then
		if EnClk2 = '1' then
			if SW4 = '0' then
				PaletkaRReg <= PaletkaRReg +1;
			elsif SW3 = '0' then
				PaletkaRReg <= PaletkaRReg - 1;
			end if;
		end if;
	end if;
end process;

process(Clk, EnClk2, SW1, SW2)
begin
	if Clk'event and Clk = '0' then
		if EnClk2 = '1' then
			if SW2 = '0' then
				PaletkaLReg <= PaletkaLReg +1;
			elsif SW1 = '0' then
				PaletkaLReg <= PaletkaLReg - 1;
			end if;
		end if;
	end if;
end process;

PaletkaL <= '1' when (((CntV >= (PaletkaLReg - "1111"))  --dekoder obrazu paletki lewej
					 and (CntV <= (PaletkaLReg + "1111"))) 
					 and  (Linia4 = '1')) else '0';
PaletkaR <= '1' when (((CntV >= (PaletkaRReg - "1111"))  --dekoder obrazu paletki prawej 
					 and (CntV <= (PaletkaRReg + "1111"))) 
					 and  (Linia5 = '1')) else '0';
					 
-------------------------GRA wyświetlacz wyników meczu---------------------- 

SegHLL <= '1' when (CntH(9 downto 3) = "0011010") else '0';
SegHU <= '1' when (CntV(9 downto 2) = "00000011") else '0';
SegHM <= '1' when (CntV(9 downto 2) = "00000110") else '0';
SegHD <= '1' when (CntV(9 downto 2) = "00001001") else '0';

SegA <= SegHLL and SegHU;
SegG <= SegHLL and SegHM;
SegD <= SegHLL and SegHD;

SegVU <= '1' when (CntV(9 downto 3) = "0000010") else '0'; 
SegVD <= '1' when ((CntV >= "0000011100") and (CntV <= ("0000011100" + "111"))) else '0'; 
SegHL <= '1' when (CntH(9 downto 2) = "00110011") else '0'; 
SegHR <= '1' when (CntH(9 downto 2) = "00110110") else '0';

SegF <= SegVU and SegHL;
SegE <= SegVD and SegHL;
SegB <= SegVU and SegHR;
SegC <= SegVD and SegHR;

Seg <= SegAand or SegBand or SegCand or SegDand or SegEand or SegFand or SegGand 
		or SegA1and or SegB1and or SegC1and or SegD1and or SegE1and or SegF1and or SegG1and;

SegHRR <= '1' when (CntH(9 downto 3) = "0110100") else '0';
SegA1 <= SegHRR and SegHU;
SegG1 <= SegHRR and SegHM;
SegD1 <= SegHRR and SegHD;

SegHL1 <= '1' when (CntH(9 downto 2) = "01100111") else '0';
SegHR1 <= '1' when (CntH(9 downto 2) = "01101010") else '0';
SegF1 <= SegVU and SegHL1;
SegE1 <= SegVD and SegHL1;
SegB1 <= SegVU and SegHR1;
SegC1 <= SegVD and SegHR1;

-------------------------GRA licznik prawego gracza----------------------

PilkaL1 <= '0' when PilkaRegH = "0000000000" else '1'; --dekoder wykroczenia piłki poza obszar boiska lewa strona
process(Clk, EnClkH, PilkaL1, PilkaRL, Reset, SWReset)
begin
	if (Reset = '0') or (SWReset = '0') then
		CntL1 <= "0000";
	else
		if Clk'event and Clk = '0' then
			if EnClkH = '1' then
				if PilkaRL = '0' then
					if PilkaL1 = '0' then
						if CntL1 = "1001" then
							null;
						else
							CntL1 <= CntL1 +1;           --licznik zdobytych punktów
						end if;
					end if;
				end if;
			end if;
		end if;
	end if;
end process;
   
    with CntL1 SELect
   SegL1 <= "1111001" when "0001",   --1					--dekoder liczby binarnej do 7 segmentowego wyświetlacza
				"0100100" when "0010",   --2
				"0110000" when "0011",   --3
				"0011001" when "0100",   --4
				"0010010" when "0101",   --5
				"0000010" when "0110",   --6
				"1111000" when "0111",   --7
				"0000000" when "1000",   --8
				"0010000" when "1001",   --9
				"1000000" when others;   --0
				
SegA1and <= (not Segl1(0)) and SegA1;  					--aktywacja odpowiednich segmentów wyniku meczu 
SegB1and <= (not Segl1(1)) and SegB1;
SegC1and <= (not Segl1(2)) and SegC1;
SegD1and <= (not Segl1(3)) and SegD1;
SegE1and <= (not Segl1(4)) and SegE1;
SegF1and <= (not Segl1(5)) and SegF1;
SegG1and <= (not Segl1(6)) and SegG1;

-------------------------GRA licznik lewego gracza----------------------

PilkaL <= '0' when PilkaRegH = "1010000000" else '1'; --dekoder wykroczenia piłki poza obszar boiska prawa strona
process(Clk, EnClkH, PilkaL, PilkaRL, Reset, SWReset)
begin
	if (Reset = '0') or (SWReset = '0') then
		CntL <= "0000";
	else
		if Clk'event and Clk = '0' then
			if EnClkH = '1' then
				if PilkaL = '0' then
					if PilkaRL = '1' then
						if CntL = "1001" then
							null;
						else
							CntL <= CntL +1;						--licznik zdobytych punktów
						end if;
					end if;
				end if;
			end if;
		end if;
	end if;
end process;
   
    with CntL SELect
   SegL <= 	"1111001" when "0001",   --1					--dekoder liczby binarnej do 7 segmentowego wyświetlacza
				"0100100" when "0010",   --2
				"0110000" when "0011",   --3
				"0011001" when "0100",   --4
				"0010010" when "0101",   --5
				"0000010" when "0110",   --6
				"1111000" when "0111",   --7
				"0000000" when "1000",   --8
				"0010000" when "1001",   --9
				"1000000" when others;   --0
				
SegAand <= (not Segl(0)) and SegA;  						--aktywacja odpowiednich segmentów wyniku meczu
SegBand <= (not Segl(1)) and SegB;
SegCand <= (not Segl(2)) and SegC;
SegDand <= (not Segl(3)) and SegD;
SegEand <= (not Segl(4)) and SegE;
SegFand <= (not Segl(5)) and SegF;
SegGand <= (not Segl(6)) and SegG;

-------------------------GRA dżwięki głośnik pizoelektryczny----------------------
process(Clk, PaletkaLEnd, PaletkaREnd, EnClk0)
begin
	if ((PaletkaLEnd = '1') or (PaletkaREnd = '1')) then --sygnał odbić piłki od paletek
		CntPizo <= (others => '0');
	else
		if Clk'event and Clk = '0' then
			if EnClk0 = '1' then
				if CntPizo = "10111" then
					null;
				else
					CntPizo <= CntPizo + 1;
				end if;
			end if;
		end if;
	end if;
end process;

BUZ <= CntV(6) and CntPizo(3); --sygnał prostokątny dla głośnika

-------------------------GRA koniec----------------------
KoniecGry <= '1' when CntL = "1001" or CntL1 = "1001" else '0'; --dekoder końca zliczania wyników

-------------------------GRA obsługa klawiatury----------------------
		process(Clk, PS2_C)								--oczekiwanie na stabilny sygnał zegarowy z klawiatury
		begin
			if PS2_C = '1' then
				Cnt <= (others => '0');
				PS2_Cin <= '1';
			else
				if Clk'event and Clk = '0' then
					if Cnt = "11111111" then
						PS2_Cin <= '0';
					else
						Cnt <= Cnt + 1;
					end if;
				end if;
			end if;
		end process;
		
		with PS2State Select
			PS2_Clk <= Ps2_Cin when idle,
			          Ps2_Cin when datain,
			          Clk when sel;
		
		process(PS2_Clk, Reset, PS2State, PS2_D)		--odbieranie danych z klawiatury w maszynie stanów
		begin
			if Reset = '0' then
				D <= "1000000000";
				Din <= "00000000";
				SW1 <= '1';
				SW2 <= '1';
				SW3 <= '1';
				SW4 <= '1';
				SWReset <= '1';
				SWPause <= '1';
				PS2State <= idle;
			else
				if PS2_Clk'event and PS2_Clk = '0' then
					case PS2State is
					
					when idle =>
								D <= "1000000000";
								PS2State <= datain;
					
					when datain =>
							if D(0) = '1' then
								D <= "1000000000";
								Din <= D(8 downto 1);
								PS2State <= sel;
							else
								D <= PS2_D & D(9 downto 1);
							end if;
					
					when sel =>
							if Din = X"F0" then
								Brake <= '1';
								PS2State <= idle;
							elsif (Din = X"15") and (Brake = '0') then	-- Q make
								SW1 <= '0';
								PS2State <= idle;
							elsif (Din = X"15") and (Brake = '1') then	-- Q brake
								SW1 <= '1';
								Brake <= '0';
								PS2State <= idle;
							elsif (Din = X"1C") and (Brake = '0') then	-- A make
								SW2 <= '0';
								PS2State <= idle;
							elsif (Din = X"1C") and (Brake = '1') then	-- A brake
								SW2 <= '1';
								Brake <= '0';
								PS2State <= idle;
							elsif (Din = X"4D") and (Brake = '0') then	-- P make
								SW3 <= '0';
								PS2State <= idle;
							elsif (Din = X"4D") and (Brake = '1') then	-- P brake
								SW3 <= '1';
								Brake <= '0';
								PS2State <= idle;
							elsif (Din = X"4B") and (Brake = '0') then	-- L make
								SW4 <= '0';
								PS2State <= idle;
							elsif (Din = X"4B") and (Brake = '1') then	-- L brake
								SW4 <= '1';
								Brake <= '0';
								PS2State <= idle;
							elsif (Din = X"29") and (Brake = '0') then	-- SPACE make
								SWReset <= '0';
								SWPause <= '1';
								PS2State <= idle;
							elsif (Din = X"29") and (Brake = '1') then	-- SPACE brake
								SWReset <= '1';
								Brake <= '0';
								PS2State <= idle;
							elsif (Din = X"5A") and (Brake = '0') then	-- ENTER make
								SWPause <= not SWPause;
								PS2State <= idle;
							elsif Brake = '1' then
								Brake <= '0';
								PS2State <= idle;
							else
								PS2State <= idle;
							end if;
							
					end case;
				end if;
			end if;
		end process;


end Behavioral;

Zdjęcia z uruchomionej gry

 

 

Pozdrawiam .

[kroszkanorber]

Mam pytanie czy kod który napisałem da się napisać w inny sposób. Mój kod opiera się głównie na komparatorach?

Sugestie mile czytane

pozdrawiam