Diody ARGB sterowane z WiFi(ESP32) reagujące na dzwięk

arek1996 · Marzec 23, 2022

Cześć,

Taki mały prosty projekt, sterujący ledami zależnie od dzwięku z wykorzystaniem ESP32, kolor doid sterowany ze smartfona z wykorzystaniem ESPAsyncWebServer i Adafruit_NeoPixel.

Jeśli chodzi o podłączenie to z zasilacza LED'ów lecą do ESP 32 masa i Vin. To wszystko podłączone do płytki na której jest rezystor 10k jako dzielnik napięcia z mikrofonem elektretowym. Do tego kondensator 10mF podłączony równolegle do tłumienia zakłóceń chociaż na pewno można, to lepiej zrobić ale nie mam wiedzy jak dobrze podłączyć mikrofon, chętnie jakieś przydatne treści przyjmę 😉 a do mikro podłączone 3.3V z ESP i analog idący do ESP między rezystorem a plusem mikrofonu(3.3).

Kod programu:

#include <Arduino.h>
#include <WiFi.h>
#include <AsyncTCP.h>
#include <ESPAsyncWebServer.h>
#include <Adafruit_NeoPixel.h>

#ifdef __AVR__
 #include <avr/power.h>
#endif

#define PIN 5
#define NUMPIXELS 120
#define DELAYVAL 10

AsyncWebServer server(80);
Adafruit_NeoPixel pixels(NUMPIXELS, PIN, NEO_GRB + NEO_KHZ800);

// REPLACE WITH YOUR NETWORK CREDENTIALS
const char* ssid = "ssid";
const char* password = "pass";

const char* PARAM_INPUT_1 = "red";
const char* PARAM_INPUT_2 = "green";
const char* PARAM_INPUT_3 = "blue";
const char* PARAM_INPUT_4 = "party";
int r = 0;
int g = 0;
int b = 0;
bool isParty = false;

int minV = 1300;
int maxV = 1500;

// HTML web page to handle 3 input fields (input1, input2, input3)
const char index_html[] PROGMEM = R"rawliteral(
<!DOCTYPE HTML><html><head>
  <title>Steruj ledami</title>
  <meta name="viewport" content="width=device-width, initial-scale=1">
  </head><body>
  <form action="/get">
    <p style="color: red;">RED: <input type="text" name="red"></p>
    <p style="color: green;">GREEN: <input type="text" name="green"></p>
    <p style="color: blue;">BLUE: <input type="text" name="blue"></p>
    <input type="checkbox" name="party" value="PARTY">
    <label for="party">Party mode</label><br><br><br>
    <input type="submit" value="Aktualizuj">
  </form>
</body></html>)rawliteral";

void notFound(AsyncWebServerRequest *request) {
  request->send(404, "text/plain", "Not found");
}

void setup() {
  #if defined(__AVR_ATtiny85__) && (F_CPU == 16000000)
  clock_prescale_set(clock_div_1);
#endif
  // END of Trinket-specific code.

  pixels.begin();
  
  Serial.begin(115200);
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  if (WiFi.waitForConnectResult() != WL_CONNECTED) {
    Serial.println("WiFi Failed!");
    return;
  }
  Serial.println();
  Serial.print("IP Address: ");
  Serial.println(WiFi.localIP());

  // Send web page with input fields to client
  server.on("/", HTTP_GET, [](AsyncWebServerRequest *request){
    request->send_P(200, "text/html", index_html);
  });

  // Send a GET request to <ESP_IP>/get?input1=<inputMessage>
  server.on("/get", HTTP_GET, [] (AsyncWebServerRequest *request) {

    if (request->hasParam(PARAM_INPUT_1)) {
      r = atoi(request->getParam(PARAM_INPUT_1)->value().c_str());
    }

    if (request->hasParam(PARAM_INPUT_2)) {
      g = atoi(request->getParam(PARAM_INPUT_2)->value().c_str());
    }

    if (request->hasParam(PARAM_INPUT_3)) {
      b = atoi(request->getParam(PARAM_INPUT_3)->value().c_str());
    }
    
    if (request->hasParam(PARAM_INPUT_4)) {
      isParty = true;
    }else
    {
      isParty = false;
    }
    request->send(200, "text/html", "Aktualizuje kolor <br><a style='font-size: 24px;' href=\"/\">POWROT</a>");
    setColor(r, g, b);
  });
  server.onNotFound(notFound);
  server.begin();
}

void loop() {
  if(isParty)
  {
    delay(15);
    float readAble = analogRead(35);
    if(readAble > minV)
    {
      float diff = maxV - minV;
      float step1 = maxV - readAble;
      int pins = NUMPIXELS;
      Serial.println(pins);
      if(step1 > 0)
      {
        pins = ((1 - (step1 / diff)) * NUMPIXELS);
      }
      setFastColor(pins);
      Serial.println(pins);
    }
  }
}

void setColor(int r, int g, int b)
{
    pixels.clear(); // Set all pixel colors to 'off'

  // The first NeoPixel in a strand is #0, second is 1, all the way up
  // to the count of pixels minus one.
  for(int i=0; i<NUMPIXELS; i++) { // For each pixel...

    // pixels.Color() takes RGB values, from 0,0,0 up to 255,255,255
    // Here we're using a moderately bright green color:
    pixels.setPixelColor(i, pixels.Color(r, g, b));
    pixels.show();   // Send the updated pixel colors to the hardware.

    delay(DELAYVAL); // Pause before next pass through loop
  }
}

void setFastColor(int pins)
{
  pixels.clear(); 
  for(int i=0; i<pins; i++) { 
    pixels.setPixelColor(i, pixels.Color(r, g, b));
  }
  pixels.show();
}

EFEKT:

Edytowano Marzec 23, 2022 przez arek1996

Gieneq · Marzec 24, 2022

@arek1996 ciekawy projekt i dziękujemy za podzielenie się nim 🙂 akurat jest to dość bliski temat do tego co robię od kilku miesiecy.

Czy myślałeś o tym, żeby zrobić możliwość wysyłania muzyki ze smartphona? Albo jakaś integrację żeby źródło dźwięku nie było prosto z ESP?

12 godzin temu, arek1996 napisał:

float readAble = analogRead(35);

Tak tylko informacyjnie, bo twój kod reaguje na niskie częstotliwości, ale jeżeli wyrzucisz z kodu Serial.print i niektóre zbędne dodatki jak np delay to uzyskasz dużo większą częstotliwość odświeżania - wbudowany SAR ADC ma max częstotliwość próbkowania 5kHz czyli z tw. Nyquista-Shannona masz pasmo czyli max częstotliwość jakie mierzysz 2,5kHz. Ale tak jest super, tylko informacyjnie piszę 🙂

Mógłbyś ewentualnie dodać jakąś inercję do paska, żeby za mocno nie skakał - zwyły wzór na przyspieszenie w ruchu z fizyki się nada. Opisałem to w moim projekcie:

Ewentualnie jak przekopiesz ten temat to coś znajdziesz dla siebie:

A tak to super projekt, powodzenia w rozwijaniu 🙂

Diody ARGB sterowane z WiFi(ESP32) reagujące na dzwięk

Pomocna odpowiedź

arek1996

Link do komentarza

Share on other sites

Gieneq

Link do komentarza

Share on other sites

Dołącz do dyskusji, napisz odpowiedź!

Quizy

Najnowsze posty w innych tematach

Który LGT8F328P użyć do urządzenia na baterię?

Kurs elektroniki – #4 – kondensatory, filtrowanie zasilania 1 2 3 4 18

Kurs Arduino - #8 - Sterowanie silnikami DC, pętla for 1 2 3 4 17

Książka do nauki

Kurs Arduino II - #10 - podsumowanie kursu 1 2 3 4

Inne