Resetowanie Arduino o określonej godzinie

[johny_duda]

Witajcie !
Mam problem, zrobiłem sobie zegarek z użyciem arduino nano, lcd oraz rtc DS1302.
Problem wygląda następująco. O północy po zmianie dnia tygodnia zegar pokazuje dwa zlane a czasem dziwnie zniekształcone napisy. Po restarcie wszystko wraca do normy. Wymyśliłem że codziennie o północy można by było takiego gagatka resetować. Tylko jest kolejny problem, po pierwsze Ja jako początkujący programista mam problem ze zrobieniem "if" tak żeby to działało a po drugie, fajnie jakby udało się to ogarnąć programowo bez dokładania kolejnych kabelków.

Poniżej wklejam kodzik który używam.

 

// I2C : SCL A5
//       SDA A4


// DS1302:  RST pin    -> Arduino Digital 2
//          DATA pin   -> Arduino Digital 3
//          CLK pin  -> Arduino Digital 4

#include <DS1302.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>


LiquidCrystal_I2C lcd(0x27, 2, 1, 0, 4, 5, 6, 7, 3, POSITIVE);


DS1302 rtc(2, 3, 4);

}

void setup()
{
  pinMode(7, INPUT_PULLUP);
  pinMode(LED_BUILTIN, OUTPUT);
  digitalWrite(LED_BUILTIN, LOW);
  // Set the clock to run-mode, and disable the write protection
  rtc.halt(false);
  rtc.writeProtect(false);

  // Setup LCD to 16x2 characters
  lcd.begin(16, 2);
  lcd.setCursor(1, 0);
  lcd.print("Made by Johny");
  lcd.setCursor(4, 1);
  lcd.createChar(0, customChar);

  delay(5000);
  lcd.clear();
  //rtc.setDate(28, 1, 2021);
  // rtc.setTime(21, 45, 00);
  //rtc.setDOW(WEDNESDAY);
  // The following lines can be commented out to use the values already stored in the DS1302
}

void loop()
{

  // Display time centered on the upper line
  lcd.setCursor(4, 0);
  lcd.print(rtc.getTimeStr());
  lcd.setCursor(1, 0);

  lcd.setCursor(14, 0);

  // Display abbreviated Day-of-Week in the lower left corner
  lcd.setCursor(0, 1);
  lcd.print(rtc.getDOWStr(FORMAT_LONG));
  // Display date in the lower right corner
  lcd.setCursor(8, 1);
  lcd.print(rtc.getDateStr(FORMAT_SHORT));
  delay(1000);
 


}

 

[slawko_k]

Po co od razu resetować. Wystarczy lcd.clear(); zrobić

Nie bawiłem się nigdy tą biblioteką i nie wiem co zwraca to rtc.getTimeStr() ale domyślam się że coś w stylu 00:00:00 (to ty wiesz najlepiej co widzisz na wyświetlaczu.

 

Zatem wstawiasz gdzieś w pętle cos w stylu

if ( rtc.getTimeStr()=="00:00:00") lcd.clear();

[Belferek]

A jak koniecznie chcesz zresetować programowo Arduino to może to pomoże:

 

[PowerTGS440]

Hej

sciągnąłem ta bibliotękę <DS1302.h> nie wiem ale tam nie ma funkcji getTimeStr() i getDateStr(). Może są różne modyfikacje, ale mniejsza z tym. Po drugie wyświetlacz też mi wywalał błąd więc w kodzie jest moja jej deklaracja ale zremowana. Twoja mi nie poszła. W pętli LOOP nie definiujemy i nie deklarujemy zmiennych a to : lcd.print(rtc.getDOWStr(FORMAT_LONG)); nie wiadomo czy Arduino nie tworzy sobie tymczasowej zmiennej STRING bo w końcu wskaźnik łańcucha znaków do wyświetlenia dostaje (nie jestem pewny) -ale lepiej w loop nie mieć nic 🙂 Arduino nigdy nie wychodzi z LOOP, o przepełnienie pamięci nie trudno.

Spróbuj ponizszego kodu, troszkę go przeorbiłem 🙂 Jak chcesz ustawic datę i czas na nowo musisz tu : #define USTAW_CZAS false     (zmienić false na true) podobnie z DEBUGEREM. Daj znać czy działa bo w sumie na sucho pisałem bo nie miałem jak sprawdzić.

#include <DS1302.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>

// LiquidCrystal_I2C lcd(0x27, 16,2);
// mi wywala bład na twojej deklaracji lcd powyzej moja na ktorej poszlo

LiquidCrystal_I2C lcd(0x27, 2, 1, 0, 4, 5, 6, 7, 3, POSITIVE);
DS1302 rtc(2, 3, 4);

#define USTAW_CZAS false                          
// przestaw na true jak chcesz przestawic czas i godzine
// przestaw na false jak juz nie chcesz aktualizowac recznie zegara i godziny

#define DEBUGER    true
// tak się oszczędza pamięć przy okazji :-) false to dużo bajtów w kieszeni !!!
// Serial'a używamy do kontroli programu głównie, jak zdefiniujemy w ten 
// sposób to kompilator przy stanie "false" pomija i nie dołącza do binarki !!!
// przestaw na false jak chcesz wylaczyc komunikaty po SERIAL
// przestaw na true jak chcesz wlaczyc komunikaty po SERIAL

String myTime;                                  // moj czas
String oldTime;                                 // bufor porownawczy
String myDate;                                  // moja data
String oldDate;                                 // bufor porownawczy

char   bufor[16] = {"                "};        // bufor czyszczacy 

unsigned long czasZERO  = 0;

// dla watkow co 1 sekunde
unsigned long thread1   = 0;
unsigned long timeout1  = 0;

//dla watkow co 1 godzine
unsigned long thread2   = 0;
unsigned long timeout2  = 0;

// --- S E T U P ------------------------------------------
void setup()
{
  pinMode(7, INPUT_PULLUP);          // do czego to ?
  pinMode(LED_BUILTIN, OUTPUT);      // ma służyć   ?
  digitalWrite(LED_BUILTIN, LOW);    // cos masz podpięte ?
  rtc.halt(false);
  rtc.writeProtect(false);
  lcd.begin(16, 2);
  lcd.setCursor(1, 0);
  lcd.print(F("Made by Johny"));     // do drukowania stringów używamy funkcji F !!!
                                     // skompilować tak - zobaczyć stan zajętej / wolnej pamięci
                                     // potem bez tego  - zobaczyś stan zajętej / wolnej pamięci
                                     // można się zdziwić, a NANO czy UNO nie są chojnie obdażone
                                     // przy większych projektach trzeba szukać oszczędności
                                     // a po drugie tak działa szybciej :-)
                                     // niż tak :                                 lcd.print("Made by Johny");
  lcd.setCursor(4, 1);               // nie wiem po co ta linijka ? zostawiam na pamiatke :)
  delay(5000);                       // barej po restarcie ;-)
  lcd.clear();      

  // wykona sie jesli #define USTAW_CZAS true
  #if USTAW_CZAS                                                                                                             
  { 
    rtc.setDate(28, 1, 2021);
    rtc.setTime(21, 45, 00);
    rtc.setDOW(WEDNESDAY);
  } 
  #endif
  
  // załacza seriala jesli #define DEBUGER true
  #if DEBUGER                                                                                               
  {
    Serial.begin(9600);  // włacz SERIAL jesli DEBUGER jest TRUE
  }
  #endif                                                                               

  UpdateClock(); 
  PokazDate();
  PokazCzas();
}

// ------------------------------------------------------------------------------------
void UpdateClock()
{
   myTime = rtc.getTimeStr();
   myDate = rtc.getDateStr();   
}
// -------------------------------------------------------------------------------------
void ClearLine(byte linia)
{  
    lcd.setCursor(0, linia);
    lcd.print(bufor); 
}
// ------------------------------------------------------------------------------------
void PokazCzas()
{
  ClearLine(0);                   // wyczysc tylko linię 0 na wyswietlaczu LCD
  lcd.setCursor(4, 0);
  lcd.print(myTime);
  
  #if DEBUGER                                                                                               
  {
    Serial.print(F("Jestem w funkcji PokazCzas(); Aktualny czas to : "));
    Serial.println(myTime);
  }
  #endif 
}
// ------------------------------------------------------------------------------------
void PokazDate()
{
  ClearLine(1);                   // wyczysc tylko linię 1 na wyswietlaczu LCD
  lcd.setCursor(0, 1);
  lcd.print(myDate);  
  
  #if DEBUGER                                                                                               
  {
    Serial.print(F("Jestem w funkcji PokazDate(); Aktualna data to : "));
    Serial.println(myDate);
  }
  #endif 
}
// ------------------------------------------------------------------------------------
void UpdateTime()
{
  oldTime = myTime;                      // zrob kopie poprzedniego czasu
  myTime = rtc.getTimeStr();             // pobierz do myTime nowy czas

  // optymalizacja :-)    po co meczyc wyswietlacz nadmiernymi bezsensownymi operacjami
  if(oldTime != myTime) PokazCzas();              // wyswietl wtedy gdy czas sie zmieni  
                                                  // jesli oldTime jest rózny od myTime
}
// ------------------------------------------------------------------------------------
void UpdateDate()
{
  oldDate = myDate;                      // zrob kopie poprzedniej daty
  myDate = rtc.getDateStr();             // pobierz do myDate nowa date

  // optymalizajca :-)    po co męczyć wyswietlacz nadmiernymi bezsensownymi operacjami
  if(oldDate != myDate) PokazDate();              // wyswietl wtedy gdy data sie zmieni 
                                                  // jeśli oldDate jest różny od myDate
}
// ------------------------------------------------------------------------------------

void loop()
{
  czasZERO = millis();
  thread1 = czasZERO - timeout1;       // watek co 1 sekunde
  thread2 = czasZERO - timeout2;       // watek co 1 godzine (nie sychronizowany z czasem realnym !)

  // wykonuj co 1 sekunde !!! --------------
  if ( thread1 >= 1000UL )
  {
    UpdateTime();             
    timeout1 = czasZERO;   

    #if DEBUGER                                                                                               
    {
      Serial.println(F("Jestem w wątku pętli LOOP(); wykonano wejsce po 1s uspienia !!!")); 
    }
    #endif 
  }

  // wykonuj co 1 godzine !!! -------------
  if ( thread2 >= 6000000UL )
  {
    UpdateDate();
    timeout2 = czasZERO;

    #if DEBUGER                                                                                               
    {
      Serial.println(F("Jestem w wątku pętli LOOP(); wykonano wejsce po 1h uspienia !!!")); 
    }
    #endif 
  }

  // --- KONIEC WATKOW -----------------------------------------------------------
  // dalej co sie chce, blokady programu nie ma :-)
}

 

Edytowano Luty 4, 2021 przez PowerTGS440

[Polecacz 101]

Produkcja i montaż PCB - wybierz sprawdzone PCBWay!
   • Darmowe płytki dla studentów i projektów non-profit
   • Tylko 5$ za 10 prototypów PCB w 24 godziny
   • Usługa projektowania PCB na zlecenie
   • Montaż PCB od 30$ + bezpłatna dostawa i szablony
   • Darmowe narzędzie do podglądu plików Gerber
Zobacz również » Film z fabryki PCBWay

[johny_duda]

@PowerTGS440

Wszystko fajnie i dzięki za kodzik ale teraz nie ma tutaj dnia tak jak to było w moim kodzie. 

Mój kod: 

 

Twój kod: 


Jeśli  była by szansa żeby jeszcze to naprawić to było by już super.

Edytowano Luty 15, 2021 przez johny_duda

[PowerTGS440]

9 godzin temu, johny_duda napisał:

@PowerTGS440

Wszystko fajnie i dzięki za kodzik ale teraz nie ma tutaj dnia tak jak to było w moim kodzie. 

Mój kod: 

 

Twój kod: 


Jeśli  była by szansa żeby jeszcze to naprawić to było by już super.

przesuń  w prawo 🙂 
masz : lcd.setCursor(0, 1); lcd.print(myDate);

czyli zrób: lcd.setCursor(3,1);  lcd.print(myDate);

lcd.setCursor(y,x); 
gdzie y to nr. kolumny
gdzie x to nr. wiersza

to co na dole zawsze można w pętli LOOP co 10sekund np. sobie zmieniać 🙂

 

 

Edytowano Luty 15, 2021 przez PowerTGS440

[kozus]

Super kod naprawdę i rozpisane krok po kroku dla początkującego super wyjaśnione :) kawał dobrej roboty :) dzięki PowerTGS440 :)