Sterownik zasilania z czasomierzem kontrolowany przez USB + aplikacja GUI w QT C++

[rziomber]

Współczesny sprzęt astronomiczny pozwala na znaczną automatyzację. Możemy więc połączyć się przez sieć z komputerem podłączonym do montażu (pulpit zdalny Windows, VNC czy linuksowy SSH). Często rolę komputera w obserwatorium spełnia Raspberry Pi, które świetnie współpracuje z pakietem INDI/EKOS. Możemy więc rozpocząć wielogodzinne zbieranie materiału i pójść spać. Montaż automatycznie podążał będzie za ruchem dobowym nieba, a kamera CCD lub CMOS zarejestruje materiał, który potem można stackować. Niestety niektóre konfiguracje sprzętu grożą zderzeniem tuby teleskopu ze statywem

lub elementami montażu paralaktycznego (np z wystającym silnikiem)

Nie powinno się więc zostawiać "samopas" włączonego teleskopu na dłuższy czas, gdyż ruch dobowy nieba może doprowadzić do "zakneblowania" mechanizmu. Stąd też pomysł sterownika zasilania, który po skończonej sesji wyłączy za nas napęd. Powinien on "rozmawiać" z portem USB komputera obserwatoryjnego, by jego działanie moglibyśmy zaprogramować zdalnie. Kolega Michał Mizera poprosił mnie o rozbudowę Jego sterownika zasilania o taką funkcjonalność. Pudełko posiada w sobie również Raspberry Pi sterujące teleskopem i sterownik grzałek odraszających. Mocowane jest bezpośrednio do montażu za pomocą rzepu. Zdjęcia za zgodą Autora:

Po wgraniu do Arduino Nano szkicu poniżej i podłączeniu do niego przekaźnika będziemy mogli sterować urządzeniem z terminala szeregowego.

• on / off - włącz / wyłącz teraz
• off - wyłącz za HH:MM:SS
• reset - zresetuj terminarz
• protectbutton / protectbuttonoff - programowe "rozbrojenie" przycisku do ręcznego sterowania, by przez przypadek niezamierzenie nie odciąć zasilania 

#define RelayPin 13
#define LEDPin 11
#define ButtonPin 2
#define RelayOnLowHigh 1 // set 0 if relay is switched on during LOW level
#define LEDbrightness 5 // PWM 0-255

String receivedData = "", command = "", receivedCommand = "";
unsigned long eventTime = 0;
unsigned long lastButtonchange = 0;
unsigned long serialTimer = 0;

bool powerStatus;
bool protectButton = 0;
void changeStatus();
void button();
String getValue(String, char, int);

void setup() {
  Serial.begin(9600);
  pinMode(RelayPin, OUTPUT);
  digitalWrite(RelayPin, LOW);
  pinMode(LEDPin, OUTPUT);
  digitalWrite(LEDPin, LOW);
  pinMode(ButtonPin, INPUT_PULLUP);
  attachInterrupt(digitalPinToInterrupt(ButtonPin), button, FALLING);
}

void loop() {
  bool status;
  String timeString = "";
  int i;
  receivedData = Serial.readStringUntil('\n');
  receivedData.toLowerCase();
  if (eventTime && millis() >= eventTime) {
    receivedData = command;
  }
  if (receivedData == "on") {
    powerStatus = 1;
    changeStatus();
  }
  if (receivedData == "off")
  {
    powerStatus = 0;
    changeStatus();
  }
  if (receivedData == "reset") {
    eventTime = 0;
    command = "";
  }
  if (receivedData == "protectbutton") {
    protectButton = 1;
  }
  if (receivedData == "protectbuttonoff") {
    protectButton = 0;
  }

  for (i = 0; (receivedData[i] < 47 || receivedData[i] > 58) && i < receivedData.length(); i++) {
    receivedCommand += receivedData[i];
  }
  if (receivedCommand == receivedData || (receivedCommand != "on" && receivedCommand != "off")) {
    receivedCommand = "";
  }
  if (receivedCommand.length()) {
    command = receivedCommand;
  }

  for (int ii = i; ii < receivedData.length(); ii++) {
    timeString += receivedData[ii];
  }
  if (timeString.length() && !eventTime && (command == "on" || command == "off") ) {
    String hours = getValue(timeString, ':', 0);
    String minuts = getValue(timeString, ':', 1);
    String seconds = getValue(timeString, ':', 2);
    eventTime = millis() + 1000 * (3600 * hours.toInt() + 60 * minuts.toInt() + seconds.toInt());
  }
  if (millis() - serialTimer >= 10000)
  {
    Serial.print("Power ");
    powerStatus ? Serial.print("ON.") : Serial.print("OFF.");
    if (eventTime) {
      Serial.print(" Turn ");
      Serial.print(command);
      Serial.print(" after ");
      unsigned long lefttime = eventTime - millis();
      unsigned long lefttimeh = lefttime / 3600000;
      lefttime = lefttime - lefttimeh * 3600000;
      Serial.print(lefttimeh);
      Serial.print("h ");
      unsigned long lefttimem = lefttime / 60000;
      lefttime = lefttime - lefttimem * 60000;
      Serial.print(lefttimem);
      Serial.print("m ");
      unsigned long lefttimes = lefttime / 1000;
      Serial.print(lefttimes);
      Serial.print("s.");
    }
    if (protectButton) {
      Serial.print(" Button locked.");

    }
    Serial.println();
    serialTimer = millis();
  }
}

void changeStatus() {
  if (!powerStatus) {
    RelayOnLowHigh ? digitalWrite(RelayPin, LOW) : digitalWrite(RelayPin, HIGH);
    digitalWrite(LEDPin, LOW);
    Serial.println("Turned OFF right now.");
  }
  else
  {
    RelayOnLowHigh ? digitalWrite(RelayPin, HIGH) : digitalWrite(RelayPin, LOW);
    analogWrite(LEDPin, LEDbrightness);
    //digitalWrite(LEDPin, HIGH);
    Serial.println("Turned ON right now.");
  }
  eventTime = 0;
  command = "";
}

void button()
{
  if ((millis() - lastButtonchange > 50) && protectButton == 0)
  {
    if (powerStatus == 0)
    {
      powerStatus = 1;
      changeStatus();
    }
    if (powerStatus == 1 && (millis() - lastButtonchange < 1500))
    {
      powerStatus = 0;
      changeStatus();
    }
  }
  lastButtonchange = millis();
}
/*
  void button()
  {
  if ((millis() - lastButtonchange > 500) && protectButton == 0)
  {
    powerStatus = !powerStatus;
    changeStatus();
  }
  lastButtonchange = millis();
  }
*/

// http://arduino.stackexchange.com/questions/1013/how-do-i-split-an-incoming-string
String getValue(String data, char separator, int index)
{
  int maxIndex = data.length() - 1;
  int j = 0;
  String chunkVal = "";

  for (int i = 0; i <= maxIndex && j <= index; i++)
  {
    chunkVal.concat(data[i]);

    if (data[i] == separator)
    {
      j++;

      if (j > index)
      {
        chunkVal.trim();
        return chunkVal;
      }

      chunkVal = "";
    }
    else if ((i == maxIndex) && (j < index)) {
      chunkVal = "";
      return chunkVal;
    }
  }
}

Dla wygody użytkowników niekoniecznie "zaprzyjaźnionych" z wpisywaniem komend dla portu szeregowego powstał program konsolowy.

Wykorzystuje on bibliotekę RS-232 for Linux, FreeBSD and windows.

Później w środowisku QT C++ dodałem interfejs graficzny.

QT to bardzo dobre środowisko do rozpoczęcia przygody ze sterowaniem elektroniką za pomocą komputera.

• bezpłatne pod warunkiem wydania naszego programu na licencji (L)GPL
• dobra dokumentacja oraz mnogość dostępnych zasobów w sieci
• oprócz GUI QT zawiera gotowe narzędzia m.in. do obsługi portu szeregowego, sieci, multimediów, w pewnym stopniu zastępuje Boost
• przenośność kodu - ten sam kod skompilujemy na Windows, MacOS, Linux, smartfony. QT Creator dostępny jest też w repozytorium Raspbiana, dzięki czemu uruchomimy nasz program na Raspberry Pi bez konieczności w tym wypadku bardzo niewygodnej cross kompilacji. Możemy więc napisać i przetestować kod na komputerze, a potem przenieść go do IDE uruchomionego na Malinie. Do instalacji w systemie Raspbian wystarczy

  sudo apt-get update
  sudo apt-get upgrade
  sudo apt-get install qtcreator gcc qtbase5-dev

  GUI "wyklikamy" przenosząc gotowe elementy z zasobnika na okno naszego programu.

"Magiczne własciwości" z kodu źródłowego C++ skorelujemy z poszczególnymi komponentami graficznymi po prawokliku:

      

Kod źródłowy programów można znaleźć na stronie projektu.

Edytowano Styczeń 28, 2019 przez rziomber

[Treker (Damian Szymański)]

Właśnie zaakceptowałem Twój opis, możesz go teraz zgłosić do akcji rabatowej umieszczając link w temacie zbiorczym. Dziękuję za przedstawienie ciekawego projektu, zachęcam do prezentowania kolejnych DIY oraz aktywności na naszym forum 🙂

[Zywis]

Na zdjęciu widzę montaż NEQ6, więc kolega pewnie używa do obsługi EQMOD, który ma już wbudowaną możliwość ustawienia limitów poruszania się montażu. Po osiągnięciu limitu montaż jest parkowany i nic mu już nie grozi.