Programowalne łopatki do gamepada

[GaladMad]

Cześć,

Ja również swoją zabawę z Arduino rozpocząłem od kursów Forbota, tym chętniej chcę przedstawić swój projekt. Jest to sprzętowy mod do gamepada wykonany na przewodowym zamienniku kontrolera z Xboxa360, który można podłączyć do komputera za pomocą portu USB. Cel jaki przyświecał mi przy tym projekcie to stworzyć maksymalnie łatwą do wykonania modyfikację, która zwiększy możliwości kontrolera, zbliżając go funkcjonalnością do serii Elite. Ponadto chciałem, aby nie przeszkadzała graczowi. Dlatego też jest ona do pewnego stopnia odwracalna – można bardzo łatwo wymontować łopatki, co przywraca w zasadzie kontroler do stanu zbliżonego do oryginalnego.

Komponenty potrzebne do modyfikacji

• rzecz jasna sam gamepad, ja użyłem nieoryginalnego przewodowego kontrolera i takie rozwiązanie ma szereg zalet. Po pierwsze drukowana płytka kontrolera jest jednostronna, wiec wszystkie potrzebne do modyfikacji komponenty mogę umieścić na spodniej stronie płytki. Dodatkowo, każdy z oryginalnych przycisków płytki posiada obok pole lutownicze, do którego łatwo przylutować przewód.
• Atmega_8, lub podobny mikrokontroler z taką samą liczbą pinów,
• 13 mikroprzełączników typu tact_switch 6x6mm z 4 wyprowadzeniami, ułatwi to lutowanie,
• 1 LED - ja wybrałem w wersji smd, aby zajmował jak najmniej miejsca. Dioda jest potrzebna do sygnalizowania stanów i potwierdzania akcji wykonanych przez użytkownika w trakcie programowania przycisków,
• rezystor do powyższego LEDa, tym razem użyłem elementu przewlekanego, ale nie ma to większego znaczenia, o ile całość zmieści się w obudowie,
• cienki przewód do połączenia wyprowadzeń z gamepada i dodanych przycisków z mikrokontrolerem.

Przydatne narzędzia

• programator do „gołej” Atmegi,
• lutownica wraz cyną, topnikiem i innymi przyborami,
• drukarka 3D do wydrukowania samych łopatek, aczkolwiek, łopatki można wykonać inną techniką,
• wkrętarka/wiertarka, lub inne narzędzie do wykonania otworów w obudowie,
• pilniki oraz papiery ścierne do wygładzania otworów,
• klej cyjanoakrylowy oraz jakaś zużyta karta debetowa lub inny materiał, który posłuży do wycięcia podkładek do d-pada i przycisków.

Wykonanie
Po pierwsze wgrałem program do mikrokontrolera. Potem odpowiednio rozmieściłem komponenty na spodniej stronie płytki kontrolera, czyli: mikrokontroler, 4 przyciski do łopatek, i przycisk funkcyjny. Następnie zaplanowałem gdzie umieszczę mały kawałek płytki perforowanej z diodą i rezystorem. W dalszej kolejności wykonałem otwory dla przycisków i niewielki wizjer na diodę.

Kolejny krok jest opcjonalny. Chodzi o zastąpienie gumek pada przyciskami tact switch. Wykonałem go, ponieważ jak się potem okazało - polutowane przewody do pól lutowniczych na płytce utrudniały działanie gumek z oryginalnych przycisków. Po wymianie gumek na mikroprzełączniki wszystko działa jak należy, bo wysokość gumek jest podobna. Jedyne co należało zrobić, to nieco zmodyfikować dolną część d-pada w sposób pokazany na zdjęciu oraz usunąć niepotrzebne gumki. Po tej podmianie przyciski akcji gamepada mają niższy skok, co zmniejsza też czas reakcji gracza. To jest dla mnie zaletą, ale wadą może być słyszalne kliknięcie.

Po tym wszystkim należy odpowiednio poprowadzić przewody od przycisków do Atmegi oraz od pinów GND i VCC do odpowiednich pinów na płytce gamepada. Następnie można złożyć cały kontroler i powkręcać wkręty.
Ostatni krok to wydrukowanie łopatek i uchwytu do nich. Uchwyt należy przykleić jak na zdjęciu. Po wydrukowaniu, zamek każdej z łopatek należy nieco przeszlifować pilnikiem, aby gładko wszedł w odpowiednie miejsce w uchwycie.

Gotowe! Od teraz można cieszyć się nowymi możliwościami starego gamepada, a w razie potrzeby wyjąć łopatki. W zależności od upodobań – wszystkie, lub tylko chwilowo nieużywane.

Działanie modyfikacji

Modyfikacja daje możliwość przypisania akcji z przycisku kontrolera do każdej z dodanych łopatek (przyciski A, B, X, Y, bumper lewy i prawy, cały D-pad oraz akcje kliknięcia z gałek analogowych). Aby zaprogramować łopatkę, należy kliknąć przycisk funkcyjny. Wówczas LED powinien się zaświecić. Jest to znak, że jesteśmy w trybie programowania łopatki. Następnie klikamy przycisk kontrolera, który chcemy zmapować; i wreszcie łopatkę, która od tej pory będzie symulowała wciśnięcie oryginalnego przycisku. Po tej akcji dioda powinna zgasnąć, sygnalizując, że przypisanie akcji się powiodło. Programowanie każdej łopatki wygląda tak samo: funkcyjny -> akcja -> łopatka. Zaprogramowane akcje przypisane do łopatek, są zapisywane w pamięci EEPROM mikrokontrolera. Nawet po wypięciu pada od komputera, ustawienia zostaną więc zapamiętane. Wciśnięcie łopatki jest interpretowane przez microchip gamepada dokładnie tak samo, jak użycie oryginalnego przycisku. Aby zresetować ustawienia, należy przytrzymać przycisk funkcyjny dłużej niż 2 sekundy.

Kod źródłowy

Muszę zaznaczyć, że metody odpowiedzialne za wpisywanie i usuwanie danych z pamięci EEPROM nie są mojego autorstwa. Zostały znalezione na jakimś forum. Niestety nie jestem w stanie znaleźć teraz autora. Dodatkowo poniższy schemat podłączenia jest tylko przykładowy. Nie ma żadnych przeciwskazań, aby pozamieniać między sobą piny odpowiadające łopatkom. Można również zamieniać między sobą piny odpowiadające przyciskom akcji. Ważne tylko, aby nie zamieniać ich z pinami z innej grupy, chociaż i tak wszystko można dostosować w kodzie źródłowym.

/*
 Name:      GamePadPaddles.ino
 Created:   7/5/2019 9:25:50 PM
 Author:   GaladMad
 Atmega8 clock 1MHz
*/
#include <EEPROM.h>

#define RUN 2
#define LED 3

int buttons[12] = { 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, A0, A1};
int paddles[4] = { A2, A3, A4, A5 };
int maps[4] = { -1, -1, -1, -1 };
int eepromAdres[4] = { 0, 2, 4, 6 };

bool saveMode = false;
int mapPin = -1;
unsigned long timer = 0;
bool resetWasDone = false;

void setup()
{
   setButtonsAsOutputs(buttons, 12);
   setButtonsAsSwitches(paddles, 4);
      
   pinMode(LED, OUTPUT);
   digitalWrite(LED, LOW);

   pinMode(RUN, INPUT_PULLUP);
   attachInterrupt(digitalPinToInterrupt(RUN), pickRun, CHANGE);

   for (int i = 0; i < 4; i++)
   {
      maps[i] = EEPROMReadInt(eepromAdres[i]);
   }
}

void loop()
{
   if (!resetWasDone)
   {
      if (!saveMode)
      {
         for (int i = 0; i < 4; i++)
         {
            if (maps[i] != -1)
            {
               if (digitalRead(paddles[i]) == LOW)
               {
                  digitalWrite(maps[i], LOW);
               }
               else
               {
                  digitalWrite(maps[i], HIGH);
               }               
            }            
         }
      }

      if (saveMode)
      {
         digitalWrite(LED, HIGH);         

         if (mapPin == -1)
         {
            //Read button
            for (int i = 0; i < 12; i++)
            {
               if (digitalRead(buttons[i]) == LOW)
               {
                  mapPin = buttons[i];
                  i = 12;
               }
            }
         }
         else
         {
            //Map paddle
            for (int i = 0; i < 4; i++)
            {
               if (digitalRead(paddles[i]) == LOW)
               {
                  maps[i] = mapPin;
                  EEPROMWriteInt(eepromAdres[i], mapPin);
                  mapPin = -1;
                  saveMode = false;
                  i = 4;
               }
            }
         }
      }
      else
      {
         digitalWrite(LED, LOW);
      }
   }
   else
   {
      blink();
      resetWasDone = false;
   }
   
}

void pickRun()
{
   if (millis() > 4000)
   {
      delay(20);
      if (digitalRead(RUN) == LOW)
         changeMode();
      else
         resetPaddles();
   }
}

void changeMode()
{
   saveMode = !saveMode;
   mapPin = -1;
   timer = millis();
}

void resetPaddles()
{
   if (millis() - timer > 2000)
   {
      for (int i = 0; i < 4; i++)
      {
         maps[i] = -1;
         EEPROMWriteInt(eepromAdres[i], -1);
      }

      mapPin = -1;
      saveMode = false;
      resetWasDone = true;
   }
}

void blink()
{
   for (int i = 0; i < 3; i++)
   {
      digitalWrite(LED, HIGH);
      delay(200);
      digitalWrite(LED, LOW);
      delay(200);
   }   
}

void setButtonsAsOutputs(int buttons[], int size)
{
   for (int i = 0; i < size; i++)
   {
      pinMode(buttons[i], OUTPUT);
      digitalWrite(buttons[i], HIGH);
   }
}

void setButtonsAsSwitches(int buttons[], int size)
{
   for(int i = 0; i < size; i++ )
   {
      pinMode(buttons[i], INPUT_PULLUP);
   }
}

//This function will write a 2 byte integer to the eeprom at the specified address and address + 1
void EEPROMWriteInt(int p_address, int p_value)
{
   byte lowByte = ((p_value >> 0) & 0xFF);
   byte highByte = ((p_value >> 8) & 0xFF);

   EEPROM.write(p_address, lowByte);
   EEPROM.write(p_address + 1, highByte);

   //Serial.println(EEPROMReadInt(p_address));
}

//This function will read a 2 byte integer from the eeprom at the specified address and address + 1
unsigned int EEPROMReadInt(int p_address)
{
   byte lowByte = EEPROM.read(p_address);
   byte highByte = EEPROM.read(p_address + 1);

   return ((lowByte << 0) & 0xFF) + ((highByte << 8) & 0xFF00);
}

// End.

 

[Treker (Damian Szymański)]

Dziękuję za opis i gratuluję ciekawego DIY! Właśnie zatwierdziłem ten temat, więc projekt jest już widoczny publicznie. Jeśli chcesz, aby Twój projekt wziął udział w naszej akcji rabatowej (50 zł do sklepu Botland) to upewnij się, że link do tego tematu umieściłeś w tym miejscu

Zachęcam do opisywania kolejnych projektów

 

[GaladMad]

Dzięki @Treker za zatwierdzenie.

Gdyby ktoś był zainteresowany, to mogę również udostępnić pliki .stl do wydrukowania łopatek i uchwytu na drukarce 3d.

[ethanak]

1 godzinę temu, GaladMad napisał:

mogę również udostępnić pliki .stl

Na pewno nie zaszkodzi. Nie zaszkodziłoby również zamieszczenie (o ile to możliwe) plików źródłowych - może ktoś będzie chciał to przerobić dla innego pada, a zawsze lepiej mieć jakąś bazę niż babrać się z przerabianiem stl-i.

[GaladMad]

W takim razie dołączam paczkę z modelami w formacie: ipt, stp i stl.

Paddles.zip