Kroczący Pseudopod - czyli dwuserwowiec który udaje, że chodzi

[ethanak]

Jakiś czas temu zacząłem się zastanawiać, czy da się zrobić kroczącego robota na dwóch serwach. Pooglądałem sobie parę filmików, i wyszło na to że owszem można - ale skręcanie będzie niemożliwe.

Ponieważ zawsze uważałem, że niemożliwe to jest włożenie hełmu na lewą stronę (chociaż podobno jeden żołnierz udowodnił że jest to możliwe kiedy wrócił nażłopany z lewizny) - postanowiłem przeanalizować, co w istniejących konstrukcjach mi się nie podoba.

No i nie spodobało mi się to, że robot mimo że przestawia sobie wszystkie nogi i tak się ślizga (nawet na trzech serwach nie da się chyba zrobic prawdziwego, precyzyjnego chodu). Postanowiłem więc, że ten "prawdziwy" chód będzie taki trochę z przymrużeniem oka, a ważniejsze jest wrażenie chodu (ech, lata pracy w teatrze lalek) i umiejętność manewrowania.

Pierwszy robot powstał w ciągu praktycznie jednej nocy - niestety, trwałość konstrukcji ze spienionego PCW poklejonego czym się dało była znikoma. Co prawda Ciapek stoi mi na biurku i powoli wymieniam wszystkie elementy tak, aby doprowadzić go do stanu pełnej używalności, ale zawsze mam coś ważniejszego do zrobienia...

Ostatnio ponieważ kupiłem kilka drobiazgów postanowiłem "pożyczyć" je do mniejszej wersji robota. Serwa były przeznaczone do kolejnej lalki, Arduino Pro Mini zawsze jakieś mi się w szufladzie pałęta, akumulatorek ma zasilać RPi Zero W, odżałowałem tylko parę drobnych elementów elektronicznych, parę śrubek i kilka metrów filamentu.

Tak że mam przyjemność przedstawić Pseudopoda - czyli robota który co prawda tak naprawdę nie chodzi, ale skrzętnie ten fakt ukrywa 🙂

Napęd robota stanowią dwa serwa Feetecha FS0307 - w stosunku do rozmiarów (najmniejsze jakie mi się udało znaleźć) mają całkiem niezły moment i prędkość. Jak widać, ruchoma jest tylko jedna (środkowa) para nóg, przednie i tylne służą jako podpory. Teoretycznie można stworzyć konstrukcję, w której będzie się ślizgać wyłącznie tylna noga podporowa, ale nie bardzo mi się chciało bawić w jakieś skomplikowane mechanizmy - szczególnie, że robot i tak pójdzie do demontażu.

Mózg to Arduino Pro Mini, zasilanie - akumulatorek LiPo 980mAh plus przetwornica MT3608. Zmysłem robota jest pojedynczy czujnik TCRT5000L, który całkiem nieźle reaguje z całkiem sporej odległości (rzędu kilku-kilkunastu cm).

Algorytm działania jest bardzo prosty: robot ma się szwendać po pokoju, co jakiś czas zmieniając sobie kierunek owego szwendania się a w przypadku napotkania na przeszkodę ma od niej odejść. Kod jest na tyle prosty, że zamieszczam go tu w całości.

#include <Servo.h>

#define VERT_PIN 10
#define HORIZ_PIN 11

#define INFRA_PIN 6
#define PHOTO_PIN A3

#define VS_ZERO 100
#define VS_MINI 85
#define VS_MAXI 125
#define HS_ZERO 80
#define HS_MINI 40
#define HS_MAXI 120

#define INFRA_STEP 40

Servo vservo, hservo;

void setup(void)
{
    pinMode(13, OUTPUT);
    pinMode(INFRA_PIN, OUTPUT);
    
    vservo.attach(VERT_PIN);
    hservo.attach(HORIZ_PIN);
    
    vservo.write(VS_ZERO);
    hservo.write(HS_ZERO);
    
}

enum {
    STEP_NO=0,
    STEP_FWD,
    STEP_BAK,
    STEP_LEFT,
    STEP_RIGHT};


uint8_t steptable[2][10]={
    {VS_ZERO, VS_ZERO, VS_MINI, VS_MAXI, VS_MAXI, VS_MINI, VS_MAXI, VS_MINI, VS_MINI, VS_MAXI},
    {VS_ZERO, VS_ZERO, VS_MAXI, VS_MINI, VS_MINI, VS_MAXI, VS_MAXI, VS_MINI, VS_MINI, VS_MAXI}};
    

void _step(int8_t lr, int8_t fwbr)
{
    int i;
    hservo.write(HS_ZERO);
    delay(100);
    vservo.write(steptable[lr][2*fwbr]);
    delay(100);
    hservo.write(lr?HS_MAXI:HS_MINI);
    delay(100);
#define SPP 7    
    for (i=1; i<=SPP; i++) {
        vservo.write(steptable[lr][2*fwbr]+ 
            ((steptable[lr][2*fwbr+1] - steptable[lr][2*fwbr]) * i) / SPP);
        delay(40);
        }
    hservo.write(HS_ZERO);
}

void step(int8_t fwbr)
{
    static int8_t s=0;
    _step(s,fwbr);
    s = !s;
}

int getPhoto(void)
{
    int a;
    digitalWrite(INFRA_PIN,1);
    delay(5);
    a=analogRead(PHOTO_PIN);
    digitalWrite(INFRA_PIN,0);
    delay(5);
    a -= analogRead(PHOTO_PIN);
    a =  a > INFRA_STEP;
    digitalWrite(13, a);
    return a;
}

bool rdz=0;

void loop()
{
    int i,n,m;
    
    
    n=random(8,12);
    for (i=0;i<n;i++) {
        if (getPhoto()) {
            if (!rdz) randomSeed(micros());
            rdz=1;
            break;
        }
        step(STEP_FWD);
    }
    n=random(4,6);
    for (i=0;i<n;i++) {
        getPhoto();
        step(STEP_BAK);
    }
    n=random(4,8);
    m=random(2) ? STEP_LEFT:STEP_RIGHT;
    for (i=0;i<n;i++) {
        getPhoto();
        step(m);
    }
}

Tak swoją drogą ciekawe, czy da się zrobić pseudopoda z jednym serwem...

 

[Chumanista]

O ile nie potrzebujesz skręcania to da się i na jednym nawet bez ślizgania:

Tylko trzeba serwo przerobić na ruch ciągły (albo dodać jakieś sprzęgło które na przykład nie przenosi ruchu poniżej określonej prędkości) 😉

[ethanak]

E tam  - tak to za proste. Zresztą widziałem takie konstrukcje z jeszcze mniejszą ilością serw, mianowicie zero  (Strandbeest) 🙂

Przy założeniu, że serwo to nie silnik tylko siłownik (tak to się chyba powinno nazywać), a pozycja dowolnej nogi jest funkcją wyłącznie położenia orczyka serwa raczej sobie tego nie wyobrażam... bo w przeciwnym razie można dokleić buty do samochodu i powiedzieć że to robot (bo przecież ma tylko jeden silnik, tupie, skręca , a takie drobiazgi jak kierownica to się nie liczą 🙂 )

[deshipu]

Swego czasu na Let's Make Robots był na to konkurs, pojawiło się kilka całkiem ciekawych konstrukcji (w tym robot pływający). I to ze skręcaniem. Oczywiście bardziej to było pełzanie, niż chodzenie.

Na szybko znalazłem takie coś:

https://www.thingiverse.com/thing:1080284

Wygląda na to, że Robotshop pokasował większość zawartości LMR po ich kupieniu, więc opisu konkursu już nie ma, zachował się tylko jeden robot: https://www.robotshop.com/community/robots/show/spidey-a-one-motor-walker-rc-version

[Polecacz 101]

Produkcja i montaż PCB - wybierz sprawdzone PCBWay!
   • Darmowe płytki dla studentów i projektów non-profit
   • Tylko 5$ za 10 prototypów PCB w 24 godziny
   • Usługa projektowania PCB na zlecenie
   • Montaż PCB od 30$ + bezpłatna dostawa i szablony
   • Darmowe narzędzie do podglądu plików Gerber
Zobacz również » Film z fabryki PCBWay

[ethanak]

Ten drugi (a przynajmniej jakiś jego odpowiednik) zachował się razem z filmem na instructables (jeśli kogoś to ciekawi).

[Silver_1]

Bardzo fajne 😄 nawet te ruchy przypominają ruchy typowego robaka 😛 podoba mi sie 😉

Zapytam tylko, co to jest „uint8_t” ? Miałem to w programie do modułu radiowego ale nie wiem za co to odpowiada

[Treker (Damian Szymański)]

8 godzin temu, Silver_1 napisał:

Zapytam tylko, co to jest „uint8_t” ? Miałem to w programie do modułu radiowego ale nie wiem za co to odpowiada

uint8_t to typ zmiennej analogiczny do byte. Nazwę można rozbić tak:

• u - unsigned (liczba bez znaku)
• int - liczba całkowita
• 8 - 8 bitów, czyli 1 Bajt.

Analogicznie istnieją typu int8_t, uint16_t  itd.