ESP32 BlueShot-I - joystick do RPi/VICE

[ethanak]

Dzisiaj taki faktycznie mały projekcik, zrealizowany (nie licząc czasu druku) w dwa popołudnia.

Od pewnego czasu chodzi za mną małe, przenośne ustrojstwo oparte na RPi, czyli taka przenośna linuksowa konsolka. No - ale sama konsolka byłaby za nudna, warto by było coś tam ciekawego zainstalować... nawet się nie zastanawiałem, i wybrałem emulator VICE.

Trochę miałem problemów, ale całość ładnie ruszyła (ekran ST7789 320x240, dźwięk I2S, nad zasilaniem jeszcze się namyślam), ale jeśli już emulacja C64 to przydałby się jakiś joystick (na podłączonej mini-klawiaturze od biedy da się pisać, ale o graniu można zapomnieć). Kupno raczej nie wchodziło w grę, poza tym konsolka ma być mała, a taki Quickshot byłby pewnie co najmniej tak duży jak ona... a chciałem żeby to był0o naprawdę małe, ale jednocześnie używalne. Tak więc trzeba było zajrzeć do swoich rupieci. I co przydatnego znalazłem:

• Wemos LOLIN32 Lite
• Joystick analogowy Waveshare (PSP1000)
• Akumulator 1200 mAh
• I oczywiście jakieś pstryczki, przełączniki i tym podobne drobiazgi,

Zacząłem oczywiście od sprawdzenia sposobu komunikacji joysticka z konsolką. Od razu założyłem, że nie ma tam być żadnych kabli - najprostsze było połączeniu BLE. Po kilku próbach doszedłem do wniosku, że joystick będzie po prostu udawać drugą klawiaturę i użyję klawiszy które nie są zmapowane na klawiaturę C64.

No i po paru próbach wyszło mi coś takiego:

Urządzenie sprawdza się nadspodziewanie dobrze, przynajmniej w prostych grach. Jedynym problemem były ostre krawędzie w pierwszej wersji obudowy, utrudniające wygodne trzymanie. Kod jest krótki (niecałe 200 linii) więc zamieszczam go w całości:

#include <BleKeyboard.h>
#include <Bounce2.h>
BleKeyboard bleKeyboard("BlueShot-I");


const uint8_t led_pin = 33;
const uint8_t key1_pin = 27;
const uint8_t key2_pin = 26;
const uint8_t fire_pin = 25;
const uint8_t x_pin=39;
const uint8_t y_pin=36;


Bounce AfButton=Bounce(), TfButton=Bounce(), FiButton=Bounce();

bool autoFire=false;
uint32_t fireDelays[]={220, 150, 100, 70, 50, 500, 330};
const int fireDelayCnt = sizeof(fireDelays) / sizeof(fireDelays[0]);
int fireDelayNo = 0;
uint32_t fireTimer;
uint32_t ledTimer;

void setup() {
    Serial.begin(115200);
    pinMode(led_pin, OUTPUT);
    digitalWrite(led_pin,1);
    pinMode(fire_pin, INPUT_PULLUP);
    AfButton.attach(key1_pin, INPUT_PULLUP);
    TfButton.attach(key2_pin, INPUT_PULLUP);
    FiButton.attach(fire_pin, INPUT_PULLUP);
    AfButton.interval(30);
    TfButton.interval(30);
    FiButton.interval(10);
  
    bleKeyboard.begin();
    ledTimer = millis();
}

int keys[2][5]={
    {KEY_NUM_8, KEY_NUM_2, KEY_NUM_4, KEY_NUM_6, KEY_NUM_0},
    {KEY_NUM_SLASH, KEY_NUM_ASTERISK, KEY_NUM_PLUS, KEY_NUM_MINUS,KEY_NUM_PERIOD}};

uint8_t keySet=0;

uint8_t lastKeys,thisKeys;

int autoFirePos(int fire)
{
    static int lastFire = 0;
    static bool fireState = false;
    if (!fire) {
        lastFire=0;
        return 0;
    }
    if (!lastFire) {
        fireTimer = millis();
        fireState=true;
        lastFire = 1;
    }
    else if (millis() - fireTimer >= fireDelays[fireDelayNo]) {
        fireState = !fireState;
        fireTimer=millis();
    }
    return fireState;
}
        
int xRead(int pin)
{
    int i,sum;
    for (i=sum=0;i<32;i++) sum+=analogRead(pin);
    return sum /32;
}

#define BIT_JU 1
#define BIT_JD 2
#define BIT_JL 4
#define BIT_JR 8

static uint8_t dirbits[]={
    BIT_JR,BIT_JR+BIT_JD, BIT_JD, BIT_JD+BIT_JL,
    BIT_JL, BIT_JL+BIT_JU, BIT_JU, BIT_JU+BIT_JR};
        
int readDirection()
{
    int x=xRead(x_pin)-1800;
    int y=xRead(y_pin)-1800;
    int w=sqrt(x*x+y*y);
    if (w < 900) return 0;
    float a = atan2(y,x) * (4.0/PI) + 4.0625;
    w=(int)a;
    return dirbits[w & 7];
}

void addKey (KeyReport *kr, uint8_t key)
{
    int i;
    if (key >= 136) key -= 136;
    else if (key >= 128) {
        kr->modifiers |= 1 << (key & 7);
        return;
    }
    for (i=0;i<6;i++) if (!kr->keys[i]) {
        kr->keys[i] = key;
        break;
    }
}

enum {
    LEDCTL_NONE=0,
    LEDCTL_AUTOFIRE,
    LEDCTL_KEYSET};
    
uint8_t ledStatus;
uint8_t ledControl=0;
uint32_t ledControlTimer;

void loop()
{
    TfButton.update();
    AfButton.update();
    FiButton.update();
    if (AfButton.rose()) {
        if (AfButton.previousDuration() > 400) {
            keySet = 1 - keySet;
            ledControl = LEDCTL_KEYSET;
            ledControlTimer = millis();
        }
        else autoFire = !autoFire;
    }
    if (TfButton.fell()) {
        if (ledControl == LEDCTL_AUTOFIRE)
            fireDelayNo = (fireDelayNo + 1) % fireDelayCnt;
        else ledControl=LEDCTL_AUTOFIRE;
        ledControlTimer = millis();
    }
    bool afToLed=false;

    if(bleKeyboard.isConnected()) {
        int i,fr;
        KeyReport kr;
        thisKeys=0;
        memset((void *)&kr,0,sizeof(kr));
        thisKeys=readDirection();
        
        fr=!FiButton.read();
        if (fr) ledControl = LEDCTL_NONE;
        if (autoFire) {
            if (fr) afToLed = true;
            fr=autoFirePos(fr);
        }
        if (afToLed) ledStatus = fr;
        else ledStatus = millis() - ledTimer <= 50;
        if (fr) thisKeys |= 1<<4;
        if (thisKeys != lastKeys) {
            for (i=0; i<5; i++) if (thisKeys & (1<<i)) addKey(&kr,keys[keySet][i]);
            lastKeys = thisKeys;
            bleKeyboard.sendReport(&kr);
            delay(10);
        }
    }
    else {
        ledStatus = millis() - ledTimer >= 100;
    }
    uint32_t delta ;
    switch(ledControl) {
        case LEDCTL_KEYSET:
        delta = (millis() - ledControlTimer)/150;
        if (delta >= 24) ledControl = LEDCTL_NONE;
        else {
            static uint8_t pls[2][8] = {
                {1,0,1,1,1,0,0,0},
                {1,1,1,0,1,0,0,0}};
            ledStatus = pls[keySet][delta & 7];
        }
        break;

        case LEDCTL_AUTOFIRE:
        delta= millis() - ledControlTimer;
        if (delta >= 3000) ledControl = LEDCTL_NONE;
        else {
            delta /= fireDelays[fireDelayNo];
            ledStatus = delta & 1;
        }
        break;
        
    }
    
    digitalWrite(led_pin, ledStatus);
    if (autoFire) {
        if (millis() - ledTimer >= 500) ledTimer = millis();
    }
    else {
        if (millis() - ledTimer >= 1000) ledTimer = millis();
    }
}

Potrzebne biblioteki: stara dobra Bounce2 i ESP32-BLE-Keyboard.

Fragment pliku sdl-vicerc dla c64:

KeySet1North=264
KeySet1East=262
KeySet1South=258
KeySet1West=260
KeySet1Fire=256
KeySet2North=267
KeySet2East=269
KeySet2South=268
KeySet2West=270
KeySet2Fire=266

Ciekawsze możliwości:

• Autofire (oczywiście włączany na żądanie) z regulowaną częstotliwością (7 możliwości od 1 do 10 Hz), zsynchronizowany z przyciskiem fire (tzn. wciśnięcie fire od razu oddaje pierwszy strzał)
• Możliwość przełączenia zestawu klawiszy (w praktyce przy odpowiednim skonfigurowaniu x64 pozwala to na szybkie przełączanie portów).
• Pojedyncza dioda w czytelny sposób podaje stan połączenia BLE, włączenie i częstotliwość autofire oraz numer zestawu klawiszy.

Schematu nie podaję bo jest trywialny - praktycznie wszystko wynika z kodu.

Będę chciał tam jeszcze jakoś zmieścić gniazdo DB9 (żeby można było Quickshota podłączyć albo inną stalową wajchę), w programie to dołączenie raptem paru linijek w funkcji readDirection.

Jakby ktoś miał jakieś pomysły - bardzo proszę o komentarz.
 

[Gieneq]

@ethanak Ciekawy projekt 🙂 niedawno myślałem, żeby zrobić coś z joystickiem do podłączenia do komputera zamiast myszy.

13 godzin temu, ethanak napisał:

nawet się nie zastanawiałem, i wybrałem emulator VICE.

i dalej piszesz o ekranie, I2S. Możesz trochę przybliżyć temat?

[matsobdev]

Ciekawi mnie pobór prądu dla ESP32, bezpośrednio z akumulatora powiedzmy, przy danym napięciu. Stan BLE podłączony.

Edytowano Październik 16, 2023 przez matsobdev

[ethanak]

1 godzinę temu, matsobdev napisał:

Ciekawi mnie pobór prądu dla ESP32

Teraz tego nie mam jak zmierzyć (nie chce mi się rozkręcać tego ustrojstwa), ale: pobór prądu z USB (z odłączonym akumulatorem żeby ładowarka nie obciążała, BLE połączony z RPi) mierzony przez INA219 to 95 mA. Biorąc pod uwagę to, że na płytce nie ma żadnej przetwornicy (zwykły LDO, chociaż z tych "naprawdę low") nie powinno być specjalnej różnicy.

 

3 godziny temu, Gieneq napisał:

dalej piszesz o ekranie, I2S. Możesz trochę przybliżyć temat?

Hm... co tu przybliżać? Zwykły RetroPie z doinstalowanym VICE ze źródełek. Dźwięk - MAX98357 (chiński odpowiednik za 13 PLN), to takie bezobsługowe cacko: podpinasz, odpalasz skrypt z Adafruit, działa. Głośniczek jakiś znajdę, plus wyjście jack na słuchawki. Ekran 2.8'' - to ten co mi przez pomyłkę wysłali ST7789 zamiast ILI9341 i nie chciałem się bawić w zwroty. Do tego odpowiednio skompilowany fbcp-ili9341. Na razie działa na RPi 3B+, ale on jest strasznie wielki i nie pasuje mi do koncepcji (chyba kupię 3A+, powinien wystarczyć). Co do zasilania jeszcze nie mam pomysłu, jak pomierzę prądy z 3A+.

Taka techniczna trudność: framebuffer jest zdaniem co poniektórych deprecated (czyli nowe wersje SDL mają go gdzieś), a drivery mipi do wyświetlaczy istnieją chyba tylko na papierze (przynajmniej nie udało mi się odpalić mimo wszelkich zaklęć i postępowania zgodnie z zeznaniami ludzi, którym to wyszło).

No - ale to temat na inny wątek 🙂

[Polecacz 101]

Produkcja i montaż PCB - wybierz sprawdzone PCBWay!
   • Darmowe płytki dla studentów i projektów non-profit
   • Tylko 5$ za 10 prototypów PCB w 24 godziny
   • Usługa projektowania PCB na zlecenie
   • Montaż PCB od 30$ + bezpłatna dostawa i szablony
   • Darmowe narzędzie do podglądu plików Gerber
Zobacz również » Film z fabryki PCBWay

[ethanak]

Tak przy okazji - może komuś potrzebny font do konsoli 6x8 (idealny do wyświetlaczy mniejszych niż 640x480)? U mnie na 320x240 wygląda tak (zrzut ekranu powiększony żeby coś było widać w przeglądarce):

Font w załączniku: Lat2-HP6x8.zip

[ethanak]

No i jeszcze drobiazg: ponieważ zależnie od ustawień konsoli vice upiera się, że KP_PERIOD to przecinek, drobna zmiana (użyję "bezpiecznego" klawisza F11):

w programie:

int keys[2][5]={
    {KEY_NUM_8, KEY_NUM_2, KEY_NUM_4, KEY_NUM_6, KEY_NUM_0},
    {KEY_NUM_SLASH, KEY_NUM_ASTERISK, KEY_NUM_PLUS, KEY_NUM_MINUS,KEY_F11}};

W pliku ustawień:

KeySet2Fire=292

 

[ethanak]

Jeszcze jeden pomysł...

Wciśniecie obu klawiszy wysyła kod F12, a joystick przełącza się na klawisze kursora i enter. Ponowne wciśnięcie klawisza przełacznika wysyła Esc, a joystick wraca do stanu w jakim był... Muszę wypróbować.

 

[H1M4W4R1]

7 minut temu, ethanak napisał:

Wciśniecie obu klawiszy wysyła kod F12, a joystick przełącza się na klawisze kursora i enter. Ponowne wciśnięcie klawisza przełacznika wysyła Esc, a joystick wraca do stanu w jakim był... Muszę wypróbować.

Konsolka nie wspiera bezpiecznych klawiszy F13-F24?

[ethanak]

A po co mi one? Akurat taki układ byłby potrzebny do sterowania Vice, tylko musiałbym jeszcze przemyśleć wysłanie poleceń load i run do C64. Ale jak znam życie coś wymyślę...